Developers, Developers, Developers! » VBScript

Replacing Parameters in Files with VBScript

Maksim Sorokin — Wed, 30 Jun 2010 14:28:13 +0000

Here is a small VBScript that replaces parameters in a file. For example you have file1 with:

Hello, my name is ${name}. I am from ${place}.

Using this VBScript replacer, you can replace those parameters and write all the contents to another file file2:

replacer.vbs file_with_parameters file_to_write key1 value1 key2 value2 ..

And here is replacer itself:

Set args = WScript.Arguments
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile(args.item(0), 1)

Set writeToFile = objFSO.CreateTextFile(args.item(1), true)

Set params = CreateObject("Scripting.Dictionary")
For i = 2 To args.Count-1 Step 2
	params.Add args.item(i), args.item(i+1)
Next

Dim arrFileLines()
i = 0
Do Until objFile.AtEndOfStream
  Redim Preserve arrFileLines(i)
  arrFileLines(i) = objFile.ReadLine
  i = i + 1
Loop
objFile.Close

For Each strLine in arrFileLines
	For Each key In params
		strLine = Replace(strLine, "${" & key & "}", params.Item(key))
	Next

  writeToFile.WriteLine(strLine)
Next
writeToFile.Close

Locating Startup Folder in Diffirent Windows Versions

Maksim Sorokin — Wed, 02 Jun 2010 16:55:30 +0000

Startup folder lets you to launch applications automatically after user logged in. Sometimes one would like to use such functionality and add own startup scripts. But the problem is that this startup folder has different locations in different Windows versions.
For example, in Windows XP:

%USERPROFILE%\Start Menu\Programs\Startup

But in Windows 7:

%APPDATA%\Microsoft\Windows\Start Menu\Programs\Startup

It is possible to determine this Startup folder through registry. Location of record in the registry is:

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders\Startup

And we can write a VBScript, which would read this registry record and create a bat file in Startup folder:

Set oShell = CreateObject("WScript.Shell")
value = oShell.RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders\Startup")

oShell.run("cmd /c echo echo hello!!1 > """ &  oShell.ExpandEnvironmentStrings(value) & """\hello.bat")

Extracting ZIP Files with VBScript

Maksim Sorokin — Mon, 24 May 2010 18:50:14 +0000

The following VBScript awaits two parameters -- the source ZIP file and target extract location:

Set args = WScript.Arguments

'The location of the zip file.
ZipFile=args.item(0)
'The folder the contents should be extracted to.
ExtractTo=args.item(1)

'If the extraction location does not exist create it.
Set fso = CreateObject("Scripting.FileSystemObject")
If NOT fso.FolderExists(ExtractTo) Then
   fso.CreateFolder(ExtractTo)
End If

'Extract the contants of the zip file.
set objShell = CreateObject("Shell.Application")
set FilesInZip=objShell.NameSpace(ZipFile).items
objShell.NameSpace(ExtractTo).CopyHere(FilesInZip)
Set fso = Nothing
Set objShell = Nothing